#TouhouDanmakufu
#Title[Deadly Sign uMulticolor Deathtrapv]
#Text[Random card by Nuclear Cheese ... be careful of this trap!]
#Player[FREE]
#ScriptVersion[2]

script_enemy_main
{
   let count;
   let count2;
   let count3;
   let count4;
   let count5;
   let angle;

   @Initialize
   {
      count = 80;
      count2 = 200;
      count3 = 440;
      count4 = 60;
      count5 = 5;
      angle = 0;
      SetLife(800);
      LoadGraphic("script\img\ExRumia.png");
      SetGraphicRect(64, 1, 127, 64);
      SetMovePosition02(GetCenterX(), 120, 60);
      SetScore(125000);
      SetTimer(60);
      SetDamageRate(14, 6);
      SetInvincibility(150);
      CutIn(YOUMU, "Deadly Sign uMulticolor Deathtrapv", 0, 0, 0, 0, 0);

      SetShotDirectionType(ABSOLUTE);
   }

   @MainLoop
   {
      count = count - 1;
      if (count <= 0)
      {
         if ((angle % 90) < 0 || (angle % 90) > 20)
         {
            let shot7 = 7;
            CreateShotA(shot7, GetX(), GetY(), 8);
            SetShotDataA(shot7, 0, 3, angle-60, 0, -0.05, 0.5, PURPLE11);
            SetShotDataA(shot7, 60, 4, 90, 0, 0, 4, PURPLE11);
            FireShot(shot7);
         }

         if ((angle % 90) < 45 || (angle % 90) > 65)
         {
            let shot1 = 1;
            CreateShotA(shot1, GetX(), GetY(), 8);
            SetShotDataA(shot1, 0, 3, angle, 0, -0.05, 0.5, RED11);
            SetShotDataA(shot1, 60, 4, 90, 0, 0, 4, RED11);
            FireShot(shot1);
         }

         if ((angle % 90) < 15 || (angle % 90) > 35)
         {
            let shot2 = 2;
            CreateShotA(shot2, GetX(), GetY(), 8);
            SetShotDataA(shot2, 0, 3, angle+60, 0, -0.05, 0.5, ORANGE11);
            SetShotDataA(shot2, 60, 4, 90, 0, 0, 4, ORANGE11);
            FireShot(shot2);
         }

         if ((angle % 90) < 60 || (angle % 90) > 80)
         {
            let shot3 = 3;
            CreateShotA(shot3, GetX(), GetY(), 8);
            SetShotDataA(shot3, 0, 3, angle+120, 0, -0.05, 0.5, YELLOW11);
            SetShotDataA(shot3, 60, 4, 90, 0, 0, 4, YELLOW11);
            FireShot(shot3);
         }

         if ((angle % 90) < 30 || (angle % 90) > 50)
         {
            let shot4 = 4;
            CreateShotA(shot4, GetX(), GetY(), 8);
            SetShotDataA(shot4, 0, 3, angle+180, 0, -0.05, 0.5, GREEN11);
            SetShotDataA(shot4, 60, 4, 90, 0, 0, 4, GREEN11);
            FireShot(shot4);
         }

         if (((angle % 90) < 75 || (angle % 90) > 95) && ((angle % 90) < -15 || (angle % 90) > 5))
         {
            let shot1 = 1;
            CreateShotA(shot1, GetX(), GetY(), 8);
            SetShotDataA(shot1, 0, 3, angle+240, 0, -0.05, 0.5, BLUE11);
            SetShotDataA(shot1, 60, 4, 90, 0, 0, 4, BLUE11);
            FireShot(shot1);
         }

         count = 3;
         angle = angle + 2;
         if (angle > 360)
         {
            angle = angle - 360;
         }
      }

      count2--;
      if (count2 <= 0)
      {
         let shot5 = 5;
         CreateLaserA(shot5, GetX(), GetY(), 400, 20, AQUA12, 30);
         SetLaserDataA(shot5, 0, -90, 0, 0, 0, 0);
         SetLaserDataA(shot5, 40, -90, -2, 0, 0, 0);
         SetLaserDataA(shot5, 121, NULL, 0, 0, 0, 0);
         SetShotKillTime(shot5, 210);
         FireShot(shot5);

         let shot6 = 6;
         CreateLaserA(shot6, GetX(), GetY(), 400, 20, AQUA12, 30);
         SetLaserDataA(shot6, 0, -90, 0, 0, 0, 0);
         SetLaserDataA(shot6, 40, -90, 2, 0, 0, 0);
         SetLaserDataA(shot6, 121, NULL, 0, 0, 0, 0);
         SetShotKillTime(shot6, 210);
         FireShot(shot6);

         count2 = 240;
      }

      count3--;
      if (count3 <= 0)
      {
         let a = GetAngleToPlayer();
         let b = -45;
         while (b <= 45)
         {
            CreateShot01(GetX(), GetY(), 2, a+b, AQUA21, 4);
            b = b + 5;
         }
         count3 = count4;

         count5--;
         if (count5 <= 0)
         {
            count5 = 5;
            if (count4 > 15)
            {
               count4 = count4 - 3;
            }
         }
      }

      SetCollisionA(GetX(), GetY(), 32);
      SetCollisionB(GetX(), GetY(), 24);
   }

   @DrawLoop
   {
      SetTexture("script\img\ExRumia.png");
      DrawGraphic(GetX(), GetY());
   }

   @Finalize
   {
      DeleteGraphic("script\img\ExRumia.png");
      let i = 0;
      while (i < 15)
      {
         CreateItem(ITEM_SCORE, GetX()+prand(-48, 48), GetY() + prand(-48, 48));
         i++;
      }
   }
}