#TouhouDanmakufu
#Title[Spiral Sign uHypnotic Spiralv]
#Text[Random card by Nuclear Cheese ... don't become hypnotized by the danmaku spiral.]
#Player[FREE]
#ScriptVersion[2]

script_enemy_main
{
   let count;
   let count2;
   let phase;
   let a;
   let da;
   @Initialize
   {
      count = 120;
      count2 = 120;
      a = 0;
      phase = 0;
      da = 1;
      SetLife(1);
      SetScore(200000);
      CutIn(YOUMU, "Spiral Sign uHypnotic Spiralv", 0, 0, 0, 0, 0);
      SetDurableSpellCard();

      SetX(GetCenterX());
      SetY(GetCenterY());

      SetTimer(132);

      SetShotDirectionType(ABSOLUTE);

   }

   @MainLoop
   {
      count--;
      if (count <= 0)
      {
         let i = 0;
         while (i < 360)
         {
            CreateShot01(GetCenterX(), GetCenterY(), 2, a+i, RED01, 10);
            if (phase >= 1 && phase < 4)
            {
               CreateShot01(GetCenterX(), GetCenterY(), 4, a+i, BLUE21, 20);
            }
            if (phase == 2)
            {
               CreateShot01(GetCenterX(), GetCenterY(), 0.5, a+i, GREEN11, 10);
            }
            if (phase >= 4)
            {
               CreateShot01(GetCenterX(), GetCenterY(), 1.6, a+i, PURPLE12, 15);
            }
            i = i + 45;
         }
         a = a + da;
         if (a > 360)
         {
            a = a - 360;
            da = da + 0.5;
            if (phase == 0 && da > 1)
            {
               phase = 1;
            }
            else if (phase == 1 && da > 1.7)
            {
               phase = 2;
            }
            else if (phase == 2 && da > 3.2)
            {
               phase = 3;
            }
            else if (phase == 3 && da > 4.7)
            {
               phase = 4;
            }
         }
         count = 5;
      }
      count2--;
      if (count2 <= 0)
      {
         if (phase == 3)
         {
            SetShotDirectionType(PLAYER);
            CreateShot01(GetClipMinX(), GetClipMinY(), 2, 0, YELLOW03, 20);
            CreateShot01(GetClipMaxX(), GetClipMinY(), 2, 0, YELLOW03, 20);
            CreateShot01(GetClipMinX(), GetClipMaxY(), 2, 0, YELLOW03, 20);
            CreateShot01(GetClipMaxX(), GetClipMaxY(), 2, 0, YELLOW03, 20);
            SetShotDirectionType(ABSOLUTE);
         }
         count2 = 120;
      }
   }

   @DrawLoop
   {
   }

   @Finalize
   {
      let i = 0;
      while (i < 22)
      {
         CreateItem(ITEM_SCORE, GetCenterX() + prand(-48, 48), 120 + prand(-48, 48));
         i++;
      }
   }
}